[ImageJ-bugs] [Bug 969] "Analyse particles" - potential bug if applied to 4-dimensional stack

[bugzilla at fiji.sc]

http://fiji.sc/bugzilla/show_bug.cgi?id=969

Wayne Rasband <wsr at nih.gov> changed:

           What    |Removed                     |Added
----------------------------------------------------------------------------
             Status|NEW                         |RESOLVED
                 CC|                            |wsr at nih.gov
         Resolution|---                         |FIXED

--- Comment #2 from Wayne Rasband <wsr at nih.gov> ---
This bug is fixed in the latest ImageJ daily build (1.49n13). The following is
a modified version of the test macro that displays the position and size of all
objects found by the particle analyzer. it omits the

   run("Convert to Mask", "method=Triangle background=Dark black stack");

statement because it is only needed when using the "Convert to Mask" command's
"Calculate threshold for each image"option.

  run("Mitosis (26MB, 5D stack)");
  run("Duplicate...", "duplicate channels=1");
  setAutoThreshold("Triangle dark");
  roiManager("reset");
  run("Analyze Particles...", "size=1-Infinity add stack");
  run("Clear Results");
  n = roiManager("count");
  for (i=0; i<n; i++) {
     roiManager("Select", i);
     Stack.getPosition(c, z, t);
     getStatistics(area, mean);
     setResult("z",i,z);
     setResult("t",i,t);
     setResult("area",i,area);
     setResult("mean",i,mean);
  }
  updateResults;
  run("Select None");

And here is a version of the macro that uses an overlay instead of the ROI
Manager:

  run("Mitosis (26MB, 5D stack)");
  run("Duplicate...", "duplicate channels=1");
  setAutoThreshold("Triangle dark");
  run("Analyze Particles...", "size=1-Infinity show=[Overlay Outlines] stack");
  run("Clear Results");
  n = Overlay.size
  for (i=0; i<n; i++) {
     Overlay.activateSelection(i)
     Stack.getPosition(c, z, t);
     getStatistics(area, mean);
     setResult("z",i,z);
     setResult("t",i,t);
     setResult("area",i,area);
     setResult("mean",i,mean);
  }
  updateResults;
  run("Select None");

-- 
You are receiving this mail because:
You are the assignee for the bug.
-------------- next part --------------
An HTML attachment was scrubbed...
URL: <http://imagej.net/pipermail/imagej-bugs/attachments/20141213/d8396404/attachment.html>