UNIT PCMD1;  {Contour lines}

INTERFACE

{$R-}   { range checking off}
{$SC+}  { short circuit AND & OR statements in IF's}
USES memtypes, OSIntf, ToolIntf, SANE, PackIntf;

CONST
	MaxPixelsPerLine = 2048;
	WhiteC = 0;
	BlackC = 255;
	{returnCodes}
	No_Change			  = 	 0;
	CMDperiod			  = -10000;
	Changed				  = -20000;
	CMDperiod_and_changed = -30000;
	
TYPE
	 PCmdBlock = RECORD
	 				Primary : ptr; {all changes are made to primary}
					Secondary : ptr; {NIL if it couldn't load, or didn't exist}
					OptionKeyDownCall : boolean;
					ShiftKeyDownCall : boolean;
					NLines : integer;
					PixelsPerLine : integer;
					BytesPerRow : integer;
					sPixelsPerLine : integer;
					sBytesPerRow : integer;
					sNLines : integer;
					RoiRect : rect;
					Rectangular : boolean; {T/F}
					mask : ptr;
					ReturnCode : OSErr; {0=okay, <0 = changed,CommandPeriod, or both}
					FgColor : integer;
					iScale:extended;   {extended - # of pixels per unit}
					iunits:string[2];  {2 characters - calibration units}
					MyOSPort : GrafPtr;
	 			 END;
	 PCmdBlockPtr = ^PcmdBlock;
				 
  	UnsignedByte=0..255;
  	LineType=PACKED ARRAY[0..MaxPixelsperLine] OF UnsignedByte;
	
				 
				 
{ MAIN entry point}


PROCEDURE  DoPCommand (pData1:PCmdBlockptr);

IMPLEMENTATION

PROCEDURE DoPCommand (pData1:PCmdBlockptr);
VAR
	pData : PCMDBlock;
	
	PROCEDURE dumbBeep;
	BEGIN
		sysbeep(1);
	END;
	
	FUNCTION blankLine : linetype;
	VAR i:integer;
		jl : linetype;
	BEGIN
		for i:=0 to MaxPixelsPerLine-1 do
			jl[i]:=whiteC;
		blankline:=jl;
	END; {blankline}
	
	PROCEDURE GetLine(h,v,count:integer; VAR line:LineType);
	VAR
		offset:LongInt;
		p:ptr;
	BEGIN
		IF pdata.primary=NIL then
			BEGIN
				line:=BlankLine;
				exit(GetLine);
			END;			
		IF (h<0) OR (v<0) OR
		   ((h+count)>pdata.PixelsPerLine)
		   OR (v>=pdata.nlines) THEN
			BEGIN
				line:=BlankLine;
				exit(GetLine);
			END;
		offset:=LongInt(v)*pdata.BytesPerRow+h;
		p:=ptr(ord4(pdata.Primary)+offset);
		BlocKMove(p,@line,count);
	END; {getline}

	PROCEDURE GetBGLine(h,v,count:integer; VAR line:LineType);
	VAR
		offset:LongInt;
		p:ptr;
	BEGIN
		IF pdata.secondary=NIL then
			BEGIN
				line:=BlankLine;
				exit(GetBGLine);
			END;			
		IF (h<0) OR (v<0) OR
		   ((h+count)>pdata.sPixelsPerLine)
		   OR (v>=pdata.snlines) THEN
			BEGIN
				line:=BlankLine;
				exit(GetBGLine);
			END;
		offset:=LongInt(v)*pdata.sBytesPerRow+h;
		p:=ptr(ord4(pdata.secondary)+offset);
		BlocKMove(p,@line,count);
	END; {getBGline}

	PROCEDURE GetMaskLine(h,v,count:integer; VAR line:LineType);
	VAR
		offset:LongInt;
		p:ptr;
	BEGIN
		IF pdata.mask=NIL then
			BEGIN
				line:=BlankLine;
				exit(GetMaskLine);
			END;			
		IF (h<0) OR (v<0) OR
		   ((h+count)>pdata.PixelsPerLine)
		   OR (v>=pdata.nlines) THEN
			BEGIN
				line:=BlankLine;
				exit(GetMaskLine);
			END;
		offset:=LongInt(v)*pdata.BytesPerRow+h;
		p:=ptr(ord4(pdata.mask)+offset);
		BlocKMove(p,@line,count);
	END; {getMaskline}
	
	PROCEDURE PutLine(h,v,count:integer; VAR line:LineType);
	VAR
		offset:LongInt;
		p:ptr;
	BEGIN
		if pdata.primary=NIL then exit(putLine);
		IF (h<0) OR (v<0) OR (v>=pdata.nlines) THEN exit(PutLine);
		IF (h+count)>pdata.PixelsPerLine THEN count:=pdata.PixelsPerLine-h;
		offset:=LongInt(v)*pdata.BytesPerRow+h;
		p:=ptr(ord4(pdata.primary)+offset);
		BlocKMove(@line,p,count);
	END;{PutLine}

	PROCEDURE GetLineUsingMask(h,v,count:integer; var line:linetype;  padcolor:integer);
	VAR {only needed when eroding/dilating & the boundaries are 
	     assumed to be a special color}
		line2 : linetype;
		i: integer;
	BEGIN
		getline (h,v,count,line);
		getline(h,v,count,line2);
		FOR i:=0 to count-1 DO
			if line2[i]<>pdata.fgcolor THEN line[i]:=padcolor;
	END;{GetLineUsingMask}
	
	PROCEDURE PutLineUsingMask(h,v,count:integer; VAR line:LineType);
	VAR
		aLine,MaskLine:LineType;
		i:integer;
	BEGIN
		GetLine(h,v,count,aline);
		GetMaskLine(h,v,count,MaskLine);
		FOR i:=0 TO count-1 DO
		IF MaskLine[i]=pdata.fgcolor THEN aLine[i]:=line[i];
		PutLine(h,v,count,aLine);
	END;

	FUNCTION CommandPeriod:boolean;
	TYPE
		KeyPtrType=^KeyMap;
	VAR
		KeyPtr:KeyPtrType;
		keys:ARRAY[0..3] OF LongInt;
		event : eventrecord;
	BEGIN
	  systemtask;
	  KeyPtr:=KeyPtrType(@keys);
	  GetKeys(KeyPtr^);
	  CommandPeriod:=(BAND(keys[1],$808000))=$808000;
	END;

	PROCEDURE SetDialogItem(TheDialog:DialogPtr; item,value:integer);
	VAR
		ItemType:integer;
		ItemBox:rect;
		ItemHdl:handle;
	BEGIN
		GetDItem (TheDialog,item,ItemType,ItemHdl,ItemBox);
		SetCtlValue(ControlHandle(ItemHdl),value)
	END;{SetDialogItem}

	PROCEDURE ShowWatch;
	VAR
		watch:CursHandle;
	BEGIN
		watch := GetCursor(WatchCursor);
		SetCursor(watch^^);
	END;

	PROCEDURE OutlineButton(theDialog: DialogPtr; itemNo, CornerRad: integer);
	{ Draws a border around a button. 16 is the normal
	  cornerRad for small buttons }
	VAR
		itemType: Integer;
		itemBox: Rect;
		itemHdl: Handle;
		tempPort: GrafPtr;
	BEGIN
		GetPort(tempPort);
		SetPort(theDialog);
		GetDItem(theDialog, itemNo, itemType, itemHdl, itemBox);
		PenSize(3, 3);
		InSetRect(itemBox, -4, -4);
		FrameRoundRect(itemBox, cornerRad, cornerRad);
		PenSize(1,1);
		SetPort(tempPort);
	END;{OutlineButton}

	FUNCTION GetDNum(TheDialog:DialogPtr; item:integer):LongInt;
	VAR
	  ItemType:integer;
	  ItemBox:rect;
	  ItemHdl:handle;
	  str:str255;
	  n:LongInt;
	BEGIN
	  GetDItem (TheDialog,item,ItemType,ItemHdl,ItemBox);
	  GetIText(ItemHdl,str);
	  {look for '.' and use everything before that character...}
	  StringToNum(str,n);
	  GetDNum:=n;
	END;

VAR
	h,c,i,j,p : integer; {for scanning entire area}
	irect : rect;
	L1,L2 : linetype; {space for 2 incoming lines}
	Result : linetype;         {result from processing}
	ptr1,ptr2,shuffle : ^linetype;  {pointing at all 3 lines}
	width,height,prec,prev,value : integer;
	ContourVal : Array[1..16] of integer;
	mylog : dialogptr;
	flag : Boolean;
	
BEGIN {contours}
	pdata:=pdata1^;
		 
	initcursor;
	p:=5; {default is 5 contours}
	mylog:=GetNewDialog(2000,nil,pointer(-1));
    OutlineButton(MyLog,ok,16);
	SelIText(MyLog,3,0,32767);
    Repeat {until OK or cancel}
    	ModalDialog(Nil,i);
    	IF (i=3) THEN
			p:=GetDNum(mylog,3); {number of contour lines}
	Until ((i=OK) and (p>=1) AND (p<=16)) or (i=cancel);
	DisposDialog(mylog);
	IF (i=cancel) THEN
		BEGIN
			pdata.ReturnCode:=pdata.ReturnCode+CMDperiod;
			pdata1^:=pdata;
			Exit(DoPCommand);
		END;
	
	pdata.ReturnCode:=changed;
	For i:=1 to p DO
		ContourVal[i]:= (i*255) DIV (p+1);
	
	irect:=pdata.roirect; {bottom is not inclusive in process area}
	with irect,pdata DO
		BEGIN
			width:=right-left;
			height:=bottom-top;
		END;
	
	{set up top 2 lines before entering loop}
	ptr1:=@L1;ptr2:=@L2; shuffle:=NIL;
	GetLine(irect.left,irect.top,width,ptr1^);
		
	FOR i:=irect.top to irect.bottom-2 DO
		BEGIN
			GetLine(irect.left,i+1,width,ptr2^);
            prec:=L2[0]; {left}
            For c:=0 to width-1 DO BEGIN
                prev :=L1[c];
                value:=L2[c];
				flag:=false;
				For h:=1 to p DO
					BEGIN
						j:=ContourVal[h];
						if      (((value<=j) and (prec>j))
							OR  ((value>j) and (prec<=j)))
							OR  (((value<=j) and (prev>j))
							OR  ((value>j) and (prev<=j)))
						THEN
							BEGIN
								result[c]:=j;
								flag:=true;
							END;
					END;{for h}
				if NOT flag then result[c]:=0;
                prec :=value;
            END; {for c}
			if pdata.rectangular
				THEN PutLine(irect.left,i,width,result)
				ELSE PutLineUsingMask(irect.left,i,width,result);
			
			shuffle:=ptr1;
			ptr1:=ptr2;
			ptr2:=shuffle;
			
			IF commandperiod then
				BEGIN
					sysbeep(1);
					pdata.ReturnCode:=pdata.ReturnCode+CMDperiod;
					pdata1^:=pdata;
					Exit(DoPCommand);
				END;
		END; {for i}
	{clone last real line into bottom}
	if pdata.rectangular
		THEN PutLine(irect.left,irect.bottom-1,width,result)
		ELSE PutLineUsingMask(irect.left,irect.bottom-1,width,result);
	pData1^:=pdata;
	
END; {DoPCommand}

END. {UNIT}